#imestate = imestate;
if (#imestate==1) imeswitch;

if (selecting) {
	#selecting = 1;
	#seltopx = seltopx;
	#seltopy = seltopy;
	#selendx = selendx;
	#selendy = selendy;
}

$char = char(inputchar("TeX Helper"));
if($char=="i"||$char=="Æ") {
	$char=char(inputchar("input next! i(t)em / item([) / i(n)put"));
	if($char=="t"||$char=="¶") insert "\\item ";
	else if($char=="["||$char=="Þ") {
		insert "\\item[] ";
		left 2;
	}
	else if($char=="n"||$char=="Ð") {
		#imestate = 0;
		insert "\\input{}";
		left 1;
	}
	else insert $char;
}

else if($char=="l"||$char=="Ø") {
	insert "\\label{}";
	left;
}

else if($char=="r"||$char=="½") {
	insert "\\ref{}";
	left;
}

else if($char=="f"||$char=="Ê") {
	if(#selecting) {
		escape;
		moveto #selendx, #selendy;
		insert "}";
		moveto #seltopx, #seltopy;
		insert "\\footnote{";
	} else {
		insert "\\footnote{}";
		left;
	}
}

else if($char=="c"||$char=="¿") {
	insert  "\\cite[]{}";
	#imestate = 0;
	left 1;
}

else if($char=="s"||$char=="Ä") {
	insertfix "\\section{}";
	right;
	while(1)  {
	$char=char(inputchar("depth of (s)ub level"));
	if ($char=="s"||$char=="Ä") insertfix "sub";
	else break;
	}
	gowordend;
	right;
}

else if($char=="p"||$char=="¾") {
	$char=char(inputchar("input next! par(t) / para(g)raph"));
	if($char=="g"||$char=="·") {insert "\\paragraph{}"; left;}
	else if($char=="t"||$char=="¶") {insert "\\part{}"; left;}
	else if($char=="r"||$char=="½") {insert "\\pageref{}"; left;}
	else insert $char;
}

else if($char=="b"||$char=="º") {
	mousemenu "quotation","quote","itemize","enumerate","description","verbatim","abstract","center","left","right","document","tabbing","tabular","ELSE";
	if(result==0) endmacro;
	else if(result==1) $strings="quotation";
	else if(result==2) $strings="quote";
	else if(result==3) $strings="itemize";
	else if(result==4) $strings="enumerate";
	else if(result==5) $strings="description";
	else if(result==6) $strings="verbatim";
	else if(result==7) $strings="abstract";
	else if(result==8) $strings="center";
	else if(result==9) $strings="flushleft";
	else if(result==10) $strings="flushright";
	else if(result==11) $strings="document";
	else if(result==12) call tabbing;
	else if(result==13) call tabular;
	else if(result==14) $strings=input("What environment?");
	if(#selecting) {
		escape;
		moveto #selendx, #selendy;
		insert "\\end{" + $strings + "}\n";
		moveto #seltopx, #seltopy;
		insert "\\begin{" + $strings + "}\n";
	} else {
		insertfix "\\begin{" + $strings + "}\n\n\n\n\\end{" + $strings + "}\n";
		down 2;
	}
}

if(#imestate) imeswitch;

endmacro;

tabbing:
	if(#selecting) {
		call select_save;
		runsync2 $hidemarudir "filter.pif /c cls ^ sed -f tabbing.sed " + $input + " | clip";
		insertfile hidemarudir + "\\tabbing.tmp";
		up 4;
		paste;
	} else {
		insertfile hidemarudir + "\\tabbing.tmp";
	}
endmacro;

tabular:
	if(#selecting) {
		call select_save;
		runsync2 $hidemarudir "filter.pif /c cls ^ sed -f tabular.sed " + $input + " | clip";
		insertfile hidemarudir + "\\tabular.tmp";
		up 4;
		paste;
	} else {
		insertfile hidemarudir + "\\tabular.tmp";
	}
endmacro;

add_pathdelim:
	$$dir = $$1;
	if (rightstr($$dir, 1) != "\\") $$dir = $$dir + "\\";
	return $$dir;

get_hidemarudir:
	call add_pathdelim hidemarudir;
	return $$return;

get_suffix:	//(filename)
	##p = strstr($$1, ".");
	if (##p == -1)
		return;
	else
		return rightstr($$1, strlen($$1) - 1 - ##p);

get_tempdir:
	$$dir = getenv("TEMP");
	if ($$dir == "") $$dir = getenv("TMP");
	if ($$dir == "") $$dir = directory;
	call add_pathdelim $$dir;
	return $$return;

select_save:
	call get_tempdir;
	$tempdir = $$return;
	call get_hidemarudir;
	$hidemarudir = $$return;
	#blockmode = true;
	#topx = seltopx; #topy = seltopy;
	#endx = selendx; #endy = selendy;
	$input = $tempdir + "_input.$$$";
	disabledraw;
	cut;
	runsync2 $hidemarudir + "clipsave.exe " + $input;
	return;